1 1 1 1 1 1 1 1 1 1 Bewertung 4.58 (12 Stimmen)

Wenn man, wie in Tabellen gleichzeitig bearbeiten beschrieben, mehrere Tabellen mit dem selben Aufbau hat, kann es zur besseren Übersicht und auch für den Ausdruck hilfreich sein, sich in einer Zelle den Tabellenblatt-Namen anzeigen zu lassen.

Tab Name

Hierfür gibt es eine Formel, die aus mehreren Funktionen besteht (verschachtelte Formel).

Markiere die Zelle, in der der Name des Tabellenblattes stehen soll und gib folgende Formel ein:

=TEIL(ZELLE("dateiname";A1);SUCHEN("]";ZELLE("dateiname";A1))+1;31)

Nach Drücken von Enter L sollte nun der Name in der Zelle stehen.
Der Vorteil: Die Zelle wird automatisch angepasst, sobald Du den Tabellenblatt-Namen änderst!

Diese Formel funktioniert nur, wenn die Datei bereits zuvor gespeichert wurde!

Wenn Du diese Formel auf alle Tabellenblätter, wie in Tabellen gleichzeitig bearbeiten beschrieben, anwendest, hast Du Ruck-Zuck jede Tabelle mit ihrem Namen versehen!

Zur Erklärung der Formel:

Ich versuche mal hier, diese verschachtelte Formel zu erläutern. Bau mal die einzelnen Schritte nach, damit Du sie nachvollziehen kannst!
Sie besteht aus drei unterschiedlichen Funktionen. Die eigentliche und zielführende Funktion ist die Funktion
=ZELLE("dateiname";A1)
Tippe sie mal in irgendeine leere Zelle ein. Als Ergebnis erhältst Du sowas hier:
C:\Documents\Office-Tipps\[3D-Summe.xlsx]Feb
Das Ergebnis liefert Dir einmal den Pfad zu der gespeicherten Datei: C:\Documents\Office-Tipps\, den Dateinamen in eckigen Klammern: [3D-Summe.xlsx] und den Namen des Tabellenblattes, in welchem die Funktion steht: Feb.

Mit der Funktion TEIL kann man aus einem Text einen Teil dieses Textes ausschneiden. Die Funktion TEIL braucht folgende Argumente:
Text: das ist der Text, aus dem ausgeschnitten werden soll - in unserem Fall das Ergebnis der Funktion ZELLE("dateiname";A1)
Erstes_Zeichen: die Position des ersten Zeichens, ab welchem ausgeschnitten werden soll. Diese ermitteln wir mit der Funktion SUCHEN
Anzahl_Zeichen: die Anzahl der Zeichen, die nach Erstes_Zeichen ausgeschnitten werden sollen. Hier geben wir 31 ein, da das die maximale Länge für Tabellenblattnamen ist.

Mit der Funktion SUCHEN kann man die Position eines Zeichens innerhalb eines Textes ermitteln. In unserem Fall suchen wir nach der Position der geschlossenen eckigen Klammer ], da diese direkt vor unserem Tabellenblattnamen steht und normalerweise nur einmal vorkommt. Die Funktion SUCHEN braucht folgende Argumente:
Suchtext: das ist das Zeichen, nach welchem wir suchen. - in unserem Fall die geschlossene eckige Klammer "]". Das Zeichen muss in Anführungsstriche gesetzt werden!
Text: der Text, in welchem wir nach dem Zeichen suchen wollen - in unserem Fall ist der Text das Ergebnis der Funtion ZELLE("dateiname";A1)
Gibst Du nun folgendes in eine leere Zelle ein:
=SUCHEN("]";ZELLE("dateiname";A1))
bekommst Du als Ergebnis eine Zahl. Das ist die Position der schließenden eckigen Klammer in dem Text
C:\Documents\Office-Tipps\[3D-Summe.xlsx]Feb
Wir brauchen aber die Position des nachfolgenden Zeichens (als erstes Zeichen des Textes, den wir mit TEIL ausschneiden wollen). Also addieren wir noch 1 dazu:
=SUCHEN("]";ZELLE("dateiname";A1))+1
Damit haben wir die Position des ersten Zeichens (in meinem Fall 50), ab dem wir mit TEIL ausschneiden wollen.

Wenn wir nun die Argumente für die Funktion TEIL einsetzen wollen, könnten wir es so schreiben:
=TEIL("C:\Documents\Office-Tipps\[3D-Summe.xlsx]Feb";50;31)
Das wäre natürlich total sinnfrei, weil nicht dynamisch! Besser, wir tauschen diese festen Werte mit den Ergebnissen der zuvor besprochenen Formeln aus:

=TEIL(ZELLE("dateiname";A1);SUCHEN("]";ZELLE("dateiname";A1))+1;31)
Und das Ergebnis lautet nun:


Feb

So einfach kann das sein! ;-)

 

Zum Seitenanfang
JSN Boot template designed by JoomlaShine.com